We are sampling items from a large lot. If the number of defectives in the lot is 3% or less, the lot is considered "good". If the defectives exceed 8%, the lot is considered "bad". We want the producer risk (probability of rejecting a good lot) to be less than or equal to 9% and the consumer risk (probability of accepting a bad lot) to be less than or equal to 5%. We need to determine N and C, where N is the minimal sample size, and C is the critical level of defectives such that, if the observed number of defectives in the sample is less than or equal to C, we accept the lot.

MODEL:

! Acceptance sampling design. From a large lot,

 take a sample of size N, accept if C or less are

 defective;

 

! Poisson approximation to number defective is used;

 

DATA:

 AQL  = .03;    ! "Good" lot fraction defective;

 LTFD = .08;    ! "Bad"  lot fraction defective;

 PRDRISK = .09; ! Tolerance for rejecting good lot;

 CONRISK = .05; ! Tolerance for accepting bad lot;

 MINSMP = 125;  ! Lower bound on sample size to

                  help solver;

ENDDATA

 

 [OBJ] MIN = N;

! Tolerance for rejecting a good lot;

  1 - @PPS( N * AQL, C) <= PRDRISK;

! Tolerance for accepting a bad lot;

  @PPS( N * LTFD, C) <= CONRISK;

! Give solver some help in getting into range;

  N >= MINSMP; C>1;

! Make variables general integer;

  @GIN( N);  @GIN( C);

END

Model: SAMSIZ