The METRIC model estimates the average number of backorders in a two level inventory system composed of a single depot or distribution center and any number of outlets served by the depot. Inventory policy at each location is described by a single number S. Whenever the sum of the amount on hand and on order drops below S, an order is placed to bring inventory back up to S. This is an evaluation model, rather than an optimization model. The user is prompted for the S values (SDEPOT and SOUTLET).

MODEL:

! The two level METRIC inventory model. ;

SETS:

 OUTLET/1..2/: ! Each outlet has a...;

  ROUTLET,  ! Resupply time from depot to outlet;

  DEM,      ! Demand rate at outlet;

  SOUTLET,  ! Stock level to use at outlet;

  ERT,      ! Effective resupply time to outlet;

  AL;       ! Average level of backlogged demand;

ENDSETS

DATA:

 ROUTLET =  2   2;

 DEM =     .1  .1;

 RDEPOT = 14;

!  Get the stock levels from the user;

 SDEPOT = ?;

 SOUTLET = ?, ?;

ENDDATA

 

! Compute total demand;

  DEM0 = @SUM( OUTLET: DEM);

! Effective expected wait at depot;

  EWT0 = @PPL( DEM0 * RDEPOT, SDEPOT)/ DEM0;

 @FOR( OUTLET( I):

! Estimate the resupply time including depot delay;

   ERT( I) = ROUTLET( I) + EWT0;

! Expected demand on backorder;

   AL( I) = @PPL( DEM( I) * ERT( I), SOUTLET( I));

 );

! Total expected demand on backorder;

 TBACK = @SUM( OUTLET: AL);

 

END

Model: METRIC